1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
|
|~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
|MOTOROLA MICROPROCESSOR & MEMORY TECHNOLOGY GROUP
|M68000 Hi-Performance Microprocessor Division
|M68060 Software Package
|Production Release P1.00 -- October 10, 1994
|
|M68060 Software Package Copyright � 1993, 1994 Motorola Inc. All rights reserved.
|
|THE SOFTWARE is provided on an "AS IS" basis and without warranty.
|To the maximum extent permitted by applicable law,
|MOTOROLA DISCLAIMS ALL WARRANTIES WHETHER EXPRESS OR IMPLIED,
|INCLUDING IMPLIED WARRANTIES OF MERCHANTABILITY OR FITNESS FOR A PARTICULAR PURPOSE
|and any warranty against infringement with regard to the SOFTWARE
|(INCLUDING ANY MODIFIED VERSIONS THEREOF) and any accompanying written materials.
|
|To the maximum extent permitted by applicable law,
|IN NO EVENT SHALL MOTOROLA BE LIABLE FOR ANY DAMAGES WHATSOEVER
|(INCLUDING WITHOUT LIMITATION, DAMAGES FOR LOSS OF BUSINESS PROFITS,
|BUSINESS INTERRUPTION, LOSS OF BUSINESS INFORMATION, OR OTHER PECUNIARY LOSS)
|ARISING OF THE USE OR INABILITY TO USE THE SOFTWARE.
|Motorola assumes no responsibility for the maintenance and support of the SOFTWARE.
|
|You are hereby granted a copyright license to use, modify, and distribute the SOFTWARE
|so long as this entire notice is retained without alteration in any modified and/or
|redistributed versions, and that such modified versions are clearly identified as such.
|No licenses are granted by implication, estoppel or otherwise under any patents
|or trademarks of Motorola, Inc.
|~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
| iskeleton.s
|
| This file contains:
| (1) example "Call-out"s
| (2) example package entry code
| (3) example "Call-out" table
|
#include <linux/linkage.h>
#include <asm/entry.h>
#include <asm/offsets.h>
|################################
| (1) EXAMPLE CALL-OUTS #
| #
| _060_isp_done() #
| _060_real_chk() #
| _060_real_divbyzero() #
| #
| _060_real_cas() #
| _060_real_cas2() #
| _060_real_lock_page() #
| _060_real_unlock_page() #
|################################
|
| _060_isp_done():
|
| This is and example main exit point for the Unimplemented Integer
| Instruction exception handler. For a normal exit, the
| _isp_unimp() branches to here so that the operating system
| can do any clean-up desired. The stack frame is the
| Unimplemented Integer Instruction stack frame with
| the PC pointing to the instruction following the instruction
| just emulated.
| To simply continue execution at the next instruction, just
| do an "rte".
|
| Linux/68k: If returning to user space, check for needed reselections.
.global _060_isp_done
_060_isp_done:
btst #0x5,%sp@ | supervisor bit set in saved SR?
beq .Lnotkern
rte
.Lnotkern:
SAVE_ALL_INT
GET_CURRENT(%d0)
tstb %curptr@(TASK_NEEDRESCHED)
jne ret_from_exception | deliver signals,
| reschedule etc..
RESTORE_ALL
|
| _060_real_chk():
|
| This is an alternate exit point for the Unimplemented Integer
| Instruction exception handler. If the instruction was a "chk2"
| and the operand was out of bounds, then _isp_unimp() creates
| a CHK exception stack frame from the Unimplemented Integer Instrcution
| stack frame and branches to this routine.
|
| Linux/68k: commented out test for tracing
.global _060_real_chk
_060_real_chk:
| tst.b (%sp) | is tracing enabled?
| bpls real_chk_end | no
|
| CHK FRAME TRACE FRAME
| ***************** *****************
| * Current PC * * Current PC *
| ***************** *****************
| * 0x2 * 0x018 * * 0x2 * 0x024 *
| ***************** *****************
| * Next * * Next *
| * PC * * PC *
| ***************** *****************
| * SR * * SR *
| ***************** *****************
|
| move.b #0x24,0x7(%sp) | set trace vecno
| bral _060_real_trace
real_chk_end:
bral trap | jump to trap handler
|
| _060_real_divbyzero:
|
| This is an alternate exit point for the Unimplemented Integer
| Instruction exception handler isp_unimp(). If the instruction is a 64-bit
| integer divide where the source operand is a zero, then the _isp_unimp()
| creates a Divide-by-zero exception stack frame from the Unimplemented
| Integer Instruction stack frame and branches to this routine.
|
| Remember that a trace exception may be pending. The code below performs
| no action associated with the "chk" exception. If tracing is enabled,
| then it create a Trace exception stack frame from the "chk" exception
| stack frame and branches to the _real_trace() entry point.
|
| Linux/68k: commented out test for tracing
.global _060_real_divbyzero
_060_real_divbyzero:
| tst.b (%sp) | is tracing enabled?
| bpls real_divbyzero_end | no
|
| DIVBYZERO FRAME TRACE FRAME
| ***************** *****************
| * Current PC * * Current PC *
| ***************** *****************
| * 0x2 * 0x014 * * 0x2 * 0x024 *
| ***************** *****************
| * Next * * Next *
| * PC * * PC *
| ***************** *****************
| * SR * * SR *
| ***************** *****************
|
| move.b #0x24,0x7(%sp) | set trace vecno
| bral _060_real_trace
real_divbyzero_end:
bral trap | jump to trap handler
|##########################
|
| _060_real_cas():
|
| Entry point for the selected cas emulation code implementation.
| If the implementation provided by the 68060ISP is sufficient,
| then this routine simply re-enters the package through _isp_cas.
|
.global _060_real_cas
_060_real_cas:
bral _I_CALL_TOP+0x80+0x08
|
| _060_real_cas2():
|
| Entry point for the selected cas2 emulation code implementation.
| If the implementation provided by the 68060ISP is sufficient,
| then this routine simply re-enters the package through _isp_cas2.
|
.global _060_real_cas2
_060_real_cas2:
bral _I_CALL_TOP+0x80+0x10
|
| _060_lock_page():
|
| Entry point for the operating system`s routine to "lock" a page
| from being paged out. This routine is needed by the cas/cas2
| algorithms so that no page faults occur within the "core" code
| region. Note: the routine must lock two pages if the operand
| spans two pages.
| NOTE: THE ROUTINE SHOULD RETURN AN FSLW VALUE IN D0 ON FAILURE
| SO THAT THE 060SP CAN CREATE A PROPER ACCESS ERROR FRAME.
| Arguments:
| a0 = operand address
| d0 = `xxxxxxff -> supervisor; `xxxxxx00 -> user
| d1 = `xxxxxxff -> longword; `xxxxxx00 -> word
| Expected outputs:
| d0 = 0 -> success; non-zero -> failure
|
| Linux/m68k: Make sure the page is properly paged in, so we use
| plpaw and handle any exception here. The kernel must not be
| preempted until _060_unlock_page(), so that the page stays mapped.
|
.global _060_real_lock_page
_060_real_lock_page:
move.l %d2,-(%sp)
| load sfc/dfc
tst.b %d0
jne 1f
moveq #1,%d0
jra 2f
1: moveq #5,%d0
2: movec.l %dfc,%d2
movec.l %d0,%dfc
movec.l %d0,%sfc
clr.l %d0
| prefetch address
.chip 68060
move.l %a0,%a1
1: plpaw (%a1)
addq.w #1,%a0
tst.b %d1
jeq 2f
addq.w #2,%a0
2: plpaw (%a0)
3: .chip 68k
| restore sfc/dfc
movec.l %d2,%dfc
movec.l %d2,%sfc
move.l (%sp)+,%d2
rts
.section __ex_table,"a"
.align 4
.long 1b,11f
.long 2b,21f
.previous
.section .fixup,"ax"
.even
11: move.l #0x020003c0,%d0
or.l %d2,%d0
swap %d0
jra 3b
21: move.l #0x02000bc0,%d0
or.l %d2,%d0
swap %d0
jra 3b
.previous
|
| _060_unlock_page():
|
| Entry point for the operating system`s routine to "unlock" a
| page that has been "locked" previously with _real_lock_page.
| Note: the routine must unlock two pages if the operand spans
| two pages.
| Arguments:
| a0 = operand address
| d0 = `xxxxxxff -> supervisor; `xxxxxx00 -> user
| d1 = `xxxxxxff -> longword; `xxxxxx00 -> word
|
| Linux/m68k: perhaps reenable preemption here...
.global _060_real_unlock_page
_060_real_unlock_page:
clr.l %d0
rts
|###########################################################################
|#################################
| (2) EXAMPLE PACKAGE ENTRY CODE #
|#################################
.global _060_isp_unimp
_060_isp_unimp:
bral _I_CALL_TOP+0x80+0x00
.global _060_isp_cas
_060_isp_cas:
bral _I_CALL_TOP+0x80+0x08
.global _060_isp_cas2
_060_isp_cas2:
bral _I_CALL_TOP+0x80+0x10
.global _060_isp_cas_finish
_060_isp_cas_finish:
bra.l _I_CALL_TOP+0x80+0x18
.global _060_isp_cas2_finish
_060_isp_cas2_finish:
bral _I_CALL_TOP+0x80+0x20
.global _060_isp_cas_inrange
_060_isp_cas_inrange:
bral _I_CALL_TOP+0x80+0x28
.global _060_isp_cas_terminate
_060_isp_cas_terminate:
bral _I_CALL_TOP+0x80+0x30
.global _060_isp_cas_restart
_060_isp_cas_restart:
bral _I_CALL_TOP+0x80+0x38
|###########################################################################
|###############################
| (3) EXAMPLE CALL-OUT SECTION #
|###############################
| The size of this section MUST be 128 bytes!!!
_I_CALL_TOP:
.long _060_real_chk - _I_CALL_TOP
.long _060_real_divbyzero - _I_CALL_TOP
.long _060_real_trace - _I_CALL_TOP
.long _060_real_access - _I_CALL_TOP
.long _060_isp_done - _I_CALL_TOP
.long _060_real_cas - _I_CALL_TOP
.long _060_real_cas2 - _I_CALL_TOP
.long _060_real_lock_page - _I_CALL_TOP
.long _060_real_unlock_page - _I_CALL_TOP
.long 0x00000000, 0x00000000, 0x00000000, 0x00000000
.long 0x00000000, 0x00000000, 0x00000000
.long _060_imem_read - _I_CALL_TOP
.long _060_dmem_read - _I_CALL_TOP
.long _060_dmem_write - _I_CALL_TOP
.long _060_imem_read_word - _I_CALL_TOP
.long _060_imem_read_long - _I_CALL_TOP
.long _060_dmem_read_byte - _I_CALL_TOP
.long _060_dmem_read_word - _I_CALL_TOP
.long _060_dmem_read_long - _I_CALL_TOP
.long _060_dmem_write_byte - _I_CALL_TOP
.long _060_dmem_write_word - _I_CALL_TOP
.long _060_dmem_write_long - _I_CALL_TOP
.long 0x00000000
.long 0x00000000, 0x00000000, 0x00000000, 0x00000000
|###########################################################################
| 060 INTEGER KERNEL PACKAGE MUST GO HERE!!!
#include "isp.sa"
|
